[meta-ti] [PATCH v2 36/37] cmb-addon-rtos: Adding CMB rtos recipe

Denys Dmytriyenko denys at ti.com
Thu Aug 24 13:13:08 PDT 2017


On Tue, Jul 18, 2017 at 07:03:47PM -0400, Mahesh Radhakrishnan wrote:
> Upstreaming the recipe for Circular Microphone array board (CMB) RTOS
> software
> Signed-off-by: Mahesh Radhakrishnan <m-radhakrishnan2 at ti.com>
> ---
> 
> v2 - Added summary
> 
>  recipes-bsp/cmb-addon/cmb-addon-rtos_git.bb | 62 +++++++++++++++++++++++++++++
>  1 file changed, 62 insertions(+)
>  create mode 100644 recipes-bsp/cmb-addon/cmb-addon-rtos_git.bb
> 
> diff --git a/recipes-bsp/cmb-addon/cmb-addon-rtos_git.bb b/recipes-bsp/cmb-addon/cmb-addon-rtos_git.bb
> new file mode 100644
> index 0000000..0ff8bba
> --- /dev/null
> +++ b/recipes-bsp/cmb-addon/cmb-addon-rtos_git.bb
> @@ -0,0 +1,62 @@
> +SUMMARY = "TI RTOS software supporting circular microphone array board"
> +require recipes-ti/includes/ti-paths.inc
> +
> +LICENSE = "BSD-3-Clause"
> +LIC_FILES_CHKSUM = "file://cmbaddonver.h;beginline=8;endline=47;md5=d0cb159bf210cfafed63042da01c83e0"
> +
> +COMPATIBLE_MACHINE = "k2g|omapl137-evm"
> +
> +PACKAGE_ARCH = "${MACHINE_ARCH}"
> +
> +CMB_ADDON_GIT_URI = "git://git.ti.com/processor-sdk/circmicarray-addon.git"
> +CMB_ADDON_GIT_PROTOCOL = "git"
> +CMB_ADDON_GIT_BRANCH = "master"
> +CMB_ADDON_GIT_DESTSUFFIX = "git/ti/addon"
> +
> +# Below commit ID corresponds to "DEV.CMB.01.01.00.00"
> +CMB_ADDON_SRCREV = "29c05572b82251bac73cd685afcffdb8549eaaaf"
> +
> +SRCREV = "${CMB_ADDON_SRCREV}"
> +PV = "01.01.00.00"
> +PR = "r0"
> +
> +BRANCH = "${CMB_ADDON_GIT_BRANCH}"
> +SRC_URI = "${CMB_ADDON_GIT_URI};destsuffix=${CMB_ADDON_GIT_DESTSUFFIX};protocol=${CMB_ADDON_GIT_PROTOCOL};branch=${BRANCH}"
> +
> +
> +S = "${WORKDIR}/git/ti/addon/cmb"
> +
> +DEPENDS = " ti-cgt6x-native \
> +            ti-sysbios \
> +            ti-xdctools \
> +            ti-pdk-build-rtos \
> +            common-csl-ip-rtos \
> +            gpio-lld-rtos \
> +            i2c-lld-rtos \
> +            mcasp-lld-rtos \
> +            board-rtos \

Blocked by board-rtos


> +"
> +
> +export C6X_GEN_INSTALL_PATH = "${STAGING_DIR_NATIVE}/usr/share/ti/cgt-c6x"
> +export PDK_INSTALL_PATH = "${PDK_INSTALL_DIR}/packages"
> +export BIOS_INSTALL_PATH = "${SYSBIOS_INSTALL_DIR}"
> +export XDC_INSTALL_PATH = "${XDC_INSTALL_DIR}"
> +
> +export XDCPATH = "${XDC_INSTALL_DIR}/packages;${SYSBIOS_INSTALL_DIR}/packages;${PDK_INSTALL_DIR}/packages"
> +
> +export PDK_CMB_ROOT_PATH = "${WORKDIR}/git"
> +
> +do_compile() {
> +    cd ${S}

Not needed ^


> +    make release LIMIT_SOCS="${TI_PDK_LIMIT_SOCS}" LIMIT_BOARDS="${TI_PDK_LIMIT_BOARDS}"
> +}
> +
> +do_install() {
> +    cd ${S}

Not needed ^


> +    install -d ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ti/addon/cmb
> +    find -name "*.tar" -exec tar xf {} -C ${D}${PDK_INSTALL_DIR_RECIPE}/packages/ \;

Is this needed?


> +}
> +
> +FILES_${PN} += "${PDK_INSTALL_DIR_RECIPE}/packages"
> -- 
> 1.9.1
> 
> -- 
> _______________________________________________
> meta-ti mailing list
> meta-ti at yoctoproject.org
> https://lists.yoctoproject.org/listinfo/meta-ti


More information about the meta-ti mailing list