[meta-fsl-arm][PATCH v2 05/10] gpu-viv-bin-mx6q: Add Vivant GPU libraries


Otavio Salvador
 

This recipe provides the binary libraries for use with iMX6 CPUs.

Change-Id: If21cf21535fc8ec4a0a1117974a8cb1f43499f66
Signed-off-by: Adrian Alonso <aalonso00@...>
Signed-off-by: Otavio Salvador <otavio@...>
---
.../gpu-viv-bin-mx6q/gpu-viv-bin-mx6q.inc | 125 ++++++++++++++++++++
.../gpu-viv-bin-mx6q/gpu-viv-bin-mx6q_12.09.01.bb | 9 ++
2 files changed, 134 insertions(+)
create mode 100644 recipes-graphics/gpu-viv-bin-mx6q/gpu-viv-bin-mx6q.inc
create mode 100644 recipes-graphics/gpu-viv-bin-mx6q/gpu-viv-bin-mx6q_12.09.01.bb

diff --git a/recipes-graphics/gpu-viv-bin-mx6q/gpu-viv-bin-mx6q.inc b/recipes-graphics/gpu-viv-bin-mx6q/gpu-viv-bin-mx6q.inc
new file mode 100644
index 0000000..4dbed04
--- /dev/null
+++ b/recipes-graphics/gpu-viv-bin-mx6q/gpu-viv-bin-mx6q.inc
@@ -0,0 +1,125 @@
+# Copyright (C) 2012 Freescale Semiconductor
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+DESCRIPTION = "GPU driver and apps for imx6"
+SECTION = "libs"
+LICENSE = "Proprietary"
+LIC_FILES_CHKSUM = "file://usr/include/gc_vdk.h;endline=11;md5=092bc28e13d678ceaebe1a40559275fb"
+PROVIDES += "virtual/libgal-x11 virtual/egl virtual/libgles1 virtual/libgles2 libvivante-dri-mx6"
+
+INC_PR = "r0"
+
+inherit fsl-eula-unpack
+
+SRC_URI = "${FSL_MIRROR}/${PN}-${PV}.bin;fsl-eula=true"
+
+PACKAGES =+ "libclc-mx6 libclc-mx6-dev libclc-mx6-dbg \
+ libegl-fb-mx6 libegl-fb-mx6-dev libegl-fb-mx6-dbg \
+ libegl-x11-mx6 libegl-x11-mx6-dev libegl-x11-mx6-dbg \
+ libgal-fb-mx6 libgal-fb-mx6-dev libgal-fb-mx6-dbg \
+ libgal-x11-mx6 libgal-x11-mx6-dev libgal-x11-mx6-dbg \
+ libgles-mx6 libgles-mx6-dev libgles-mx6-dbg \
+ libgles2-mx6 libgles2-mx6-dev libgles2-mx6-dbg \
+ libgl-mx6 libgl-mx6-dev libgl-mx6-dbg \
+ libglslc-mx6 libglslc-mx6-dev libglslc-mx6-dbg \
+ libopencl-mx6 libopencl-mx6-dev libopencl-mx6-dbg \
+ libopevg-mx6 libopevg-mx6-dev libopevg-mx6-dbg \
+ libvdk-mx6 libvdk-mx6-dev libvdk-mx6-dbg \
+ libvivante-mx6 libvivante-mx6-dev libvivante-mx6-dbg \
+ libvivante-dri-mx6 libvivante-dri-mx6-dev libvivante-dri-mx6-dbg \
+ "
+
+# FIXME: The provided binary doesn't provide soname. If in future BSP
+# release the libraries are fixed, we can drop this hack.
+SOLIBS = "${SOLIBSDEV}"
+
+# FIXME: All binaries lack GNU_HASH in elf binary but as we don't have
+# the source we cannot fix it. Disable the insane check for now.
+python __anonymous() {
+ packages = d.getVar('PACKAGES', True).split()
+ for p in packages:
+ d.setVar("INSANE_SKIP_%s" % p, "ldflags")
+}
+
+do_install () {
+ install -d ${D}${libdir}/dri
+ install -d ${D}${includedir}
+
+ cp ${S}/usr/lib/*.so ${D}${libdir}
+ cp -axr ${S}/usr/include/* ${D}${includedir}
+
+ # Move DRI library to proper path
+ mv ${D}${libdir}/vivante_dri.so ${D}${libdir}/dri
+
+ find ${D}${libdir} -type f -exec chmod 644 {} \;
+ find ${D}${includedir} -type f -exec chmod 644 {} \;
+}
+
+S = "${WORKDIR}/${PN}-${PV}"
+
+FILES_${PN} = "${libdir} ${libdir}/dri"
+FILES_${PN}-dev = "${includedir}"
+FILES_${PN}-dbg = "${libdir}/.debug ${libdir}/dri/.debug"
+
+FILES_libclc-mx6 = "${libdir}/libCLC${SOLIBS}"
+FILES_libclc-mx6-dev = "${includedir}/CL ${libdir}/libCLC${SOLIBSDEV}"
+FILES_libclc-mx6-dbg = "${libdir}/.debug/libCLC${SOLIBS}"
+
+FILES_libegl-fb-mx6 = "${libdir}/libEGL-fb${SOLIBS}"
+FILES_libegl-fb-mx6-dev = "${includedir}/EGL ${libdir}/libEGL-fb${SOLIBSDEV}"
+FILES_libegl-fb-mx6-dbg = "${libdir}/.debug/libEGL-fb${SOLIBS}"
+
+FILES_libegl-x11-mx6 = "${libdir}/libEGL-x11${SOLIBS}"
+FILES_libegl-x11-mx6-dev = "${includedir}/EGL ${libdir}/libEGL-x11${SOLIBSDEV}"
+FILES_libegl-x11-mx6-dbg = "${libdir}/.debug/libEGL-x11${SOLIBS}"
+
+FILES_libgal-fb-mx6 = "${libdir}/libGAL-fb${SOLIBS}"
+FILES_libgal-fb-mx6-dev = "${includedir}/HAL ${libdir}/libGAL-fb${SOLIBSDEV}"
+FILES_libgal-fb-mx6-dbg = "${libdir}/.debug/libGAL-fb${SOLIBS}"
+
+FILES_libgal-x11-mx6 = "${libdir}/libGAL-x11${SOLIBS}"
+FILES_libgal-x11-mx6-dev = "${includedir}/HAL ${libdir}/libGAL-x11${SOLIBSDEV}"
+FILES_libgal-x11-mx6-dbg = "${libdir}/.debug/libGAL-x11${SOLIBS}"
+
+FILES_libgles-mx6 = "${libdir}/libGLESv1*${SOLIBS} ${libdir}/libGLES_*${SOLIBS}"
+FILES_libgles-mx6-dev = "${includedir}/GLES ${libdir}/libGLESv1*${SOLIBS} ${libdir}/libGLES_*${SOLIBSDEV}"
+FILES_libgles-mx6-dbg = "${libdir}/.debug/libGLESv1*${SOLIBS} ${libdir}/.debug/libGLES_*${SOLIBS}"
+
+FILES_libgles2-mx6 = "${libdir}/libGLESv2${SOLIBS}"
+FILES_libgles2-mx6-dev = "${includedir}/GLES2 ${libdir}/libGLESv2${SOLIBSDEV}"
+FILES_libgles2-mx6-dbg = "${libdir}/.debug/libGLESv2${SOLIBS}"
+
+FILES_libgl-mx6 = "${libdir}/libGL${SOLIBS}"
+FILES_libgl-mx6-dev = "${includedir}/GL ${libdir}/libGL${SOLIBSDEV}"
+FILES_libgl-mx6-dbg = "${libdir}/.debug/libGL${SOLIBS}"
+
+FILES_libglslc-mx6 = "${libdir}/libGLSLC${SOLIBS}"
+FILES_libglslc-mx6-dev = "${includedir}/CL ${libdir}/libGLSLC${SOLIBSDEV}"
+FILES_libglslc-mx6-dbg = "${libdir}/.debug/libGLSLC${SOLIBS}"
+
+FILES_libopencl-mx6 = "${libdir}/libOpenCL${SOLIBS}"
+FILES_libopencl-mx6-dev = "${includedir}/CL ${libdir}/libOpenCL${SOLIBSDEV}"
+FILES_libopencl-mx6-dbg = "${libdir}/.debug/libOpenCL${SOLIBS}"
+
+FILES_libopenvg-mx6 = "${libdir}/libOpenVG*${SOLIBS}"
+FILES_libopenvg-mx6-dev = "${includedir}/VG ${libdir}/libOpenVG*${SOLIBSDEV}"
+FILES_libopenvg-mx6-dbg = "${libdir}/.debug/libOpenVG*${SOLIBS}"
+
+FILES_libvdk-mx6 = "${libdir}/libVDK${SOLIBS}"
+FILES_libvdk-mx6-dev = "${includedir}/*vdk.h ${libdir}/libVDK${SOLIBSDEV}"
+FILES_libvdk-mx6-dbg = "${libdir}/.debug/libVDK${SOLIBS}"
+
+FILES_libvivante-fb-mx6 = "${libdir}/libVIVANTE-fb${SOLIBS}"
+FILES_libvivante-fb-mx6-dev = "${includedir}/HAL ${libdir}/libVIVANTE-fb${SOLIBSDEV}"
+FILES_libvivante-fb-mx6-dbg = "${libdir}/.debug/libVIVANTE-fb${SOLIBS}"
+
+FILES_libvivante-x11-mx6 = "${libdir}/libVIVANTE-x11${SOLIBS}"
+FILES_libvivante-x11-mx6-dev = "${includedir}/HAL ${libdir}/libVIVANTE-x11${SOLIBSDEV}"
+FILES_libvivante-x11-mx6-dbg = "${libdir}/.debug/libVIVANTE-x11${SOLIBS}"
+
+FILES_libvivante-dri-mx6 = "${libdir}/dri/vivante_dri${SOLIBS}"
+FILES_libvivante-dri-mx6-dev = ""
+FILES_libvivante-dri-mx6-dbg = "${libdir}/dri/.debug/vivante_dri${SOLIBS}"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+COMPATIBLE_MACHINE = "(mx6)"
diff --git a/recipes-graphics/gpu-viv-bin-mx6q/gpu-viv-bin-mx6q_12.09.01.bb b/recipes-graphics/gpu-viv-bin-mx6q/gpu-viv-bin-mx6q_12.09.01.bb
new file mode 100644
index 0000000..c54ad19
--- /dev/null
+++ b/recipes-graphics/gpu-viv-bin-mx6q/gpu-viv-bin-mx6q_12.09.01.bb
@@ -0,0 +1,9 @@
+# Copyright (C) 2012 Freescale Semiconductor
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+PR = "${INC_PR}.0"
+
+include gpu-viv-bin-mx6q.inc
+
+SRC_URI[md5sum] = "9f2c43b6eae468df6cc6fd75efd00bc5"
+SRC_URI[sha256sum] = "2cec10c1d69bce75a7c2a4482eb3ed29b171578c3b01c5b4ef2cc868ca327330"
--
1.7.10.4

Join meta-freescale@lists.yoctoproject.org to automatically receive all group messages.